Z osa feed rate problém

[CrazyHUNTER]

Zdravím,
Po delší době jsem opět začal pracovat s tiskárnou a vyskytl se takový problém.
Ve vygenerovaném G-codu je feed rate pro zvednutí vrstvy 7800, ale co jsem ručně zkoušel tiskárna nezvládá víc jak 150. Někde jsem četl, že software tiskárny by to měl omezovat automaticky a přes jeho max hodnotu to nepustit, ale mě to prostě ignoruje a potom se zaseknou motory.

Nevíte někdo jak to opravit??? Díky

[Bobici]

a cim generujes ten gcode? nemas to jen na zacatku tisku, pote co se vyhreje tryska a Z se vraci na prvni vrstvu?

[CrazyHUNTER]

generuju pres Slicer a tento problém je u všech vrstev spíš si myslím jestli to nebude něco v nastavení softu tiskárny ale nemám ponětí co

[Bobici]

udelal jsem ti script ve vbscriptu, ktery ve vygenerovanem .gcodu nastavi nove rychlosti pohybu Z osy, take ho mozna zacnu pouzivat

staci vytvorit soubor "change_z.vbs" a vlozit do nej nize uvedeny obsah
parametry jsou:
vstupni soubor (.gcode)
vystupni soubor (.gcode)
nova rychlost (napr. 150)

priklad spusteni z prikazove radky:

Kód: Vybrat vše

  change_z.vbs  tisk.gcode tisk_upr.gcode 150

obsah change_z.vbs

Kód: Vybrat vše

'/******************************************************************************
' change_z.vbs
' zmeni rychlosti posunu osy Z ve vygenerovanem gcode
' 1.0   27.08.2014  bobici
'******************************************************************************/

Option Explicit

''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Input parameters and help
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub Args (p_par1, p_par2, p_par3)
  Dim oArgs
 
  Set oArgs = WScript.Arguments
  if oArgs.count = 3  then
    p_par1  =  oArgs(0)
    p_par2  =  oArgs(1)
    p_par3  =  oArgs(2)
  else
    call HelpDisp
    Wscript.Quit
  end if
  if p_par1 = p_par2 then
    call HelpDisp
    Wscript.Quit
  end if
End Sub

Sub HelpDisp
  Dim NewLine
  NewLine = Chr(13) & Chr(10)
  wscript.echo "Nápověda:" & NewLine & _
               "utilita vyžaduje 3 povinné parametry "& NewLine &_
               "  1. vstupní soubor"& NewLine &_
               "  2. výstupní soubor"& NewLine &_               
               "  3. nová rychlost"& NewLine               
End Sub

Dim inFileName, outFileName, line, nSpeed, nF_Pos
Dim objFSO, objInFile, objOutFile

call Args (inFileName, outFileName, nSpeed)
' Create Objects, Open/Create files
Set objFSO = CreateObject("Scripting.FileSystemObject")
wscript.echo    inFileName
Set objInFile = objFSO.OpenTextFile(inFileName, 1, False, 0)
Set objOutFile = objFSO.CreateTextFile(outFileName, true)
' Copy and Replace
Do Until objInFile.AtEndOfStream
  line = objInFile.Readline
  if (Left(line, 2) = "G0" or Left(line, 2) = "G1") then
    if (InStr(line, "Z") > 0) then
     nF_Pos = InStr(line, "F")
     if nF_Pos > 0 then
       line = Left(line, nF_Pos) & nSpeed
     end if
   end if
  end if
  objOutFile.WriteLine(line)
Loop
' Close Files
objOutFile.Close
objInFile.Close
set objOutFile = Nothing
set objInFile = Nothing
set objFSO = Nothing


[CrazyHUNTER]

Ok dík určitě zkusím, ale právě jsem na řešení přišel stačilo když jsem na začátek gcodu dal m203 z120 a tím pádem mi to už nad ten feed rate 120 nepustí ale proč to nefungovalo rovnou nevím.

Každopádně díky za tvůj čas a kdyby to zas přestalo fungovat budu používat to co jsi poslal.

[Bobici]

no tak super, v podstate se da ten muj kod upravit na cokoliv jineho

[oscar]

obdivuju lidi co pisi ve visual basicu. ...